build.gradle

plugins {
    id 'java'
    id 'application'
    id 'distribution'
    id 'com.github.jk1.dependency-license-report' version '2.0'
    id "com.diffplug.spotless" version "6.25.0"
}

group 'org.jlab'
version new File("${projectDir}/VERSION").text.trim()
ext.releaseDate = new Date().format('MMM dd yyyy')

tasks.withType(JavaCompile).configureEach {
    options.release = 11
    options.encoding = 'UTF-8'
    options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
}

repositories {
    mavenCentral()

    maven {
        url "https://packages.confluent.io/maven"
    }
}

dependencies {
    implementation "org.apache.kafka:kafka-streams:3.5.0",
                "io.confluent:kafka-streams-avro-serde:7.4.0",
                "org.apache.avro:avro:1.11.2",
                "org.slf4j:slf4j-log4j12:1.7.36",
                "org.jlab:jaws-libj:5.0.0"
    testImplementation "org.apache.kafka:kafka-streams-test-utils:3.5.0",
                "junit:junit:4.13.2"
}

test {
    testLogging {
        events "passed", "skipped", "failed"
        exceptionFormat "full"
    }
}

jar {
    archiveFileName = 'jaws-registrations2epics.jar'
}

application {
    mainClass.set('org.jlab.jaws.Registrations2Epics')
}

build {
    dependsOn(installDist)
}

installDist.dependsOn(generateLicenseReport)
distTar.dependsOn(generateLicenseReport)
distZip.dependsOn(generateLicenseReport)

run {
    classpath += files('src/test/resources')
    environment "BOOTSTRAP_SERVERS", "localhost:9094"
    environment "SCHEMA_REGISTRY", "http://localhost:8081"
    environment "STATE_DIR", project.file('build/kafka-streams')
    environment "CREATE_SOURCE_TOPIC", "yes"
}

distributions {
    main {
        contents {
            from("build/reports/dependency-license") {
                into "dependency-license"
            }
            from('config') {
                into 'config'
            }
        }
    }
}

startScripts {
    classpath += files('config')

    // https://discuss.gradle.org/t/classpath-in-application-plugin-is-building-always-relative-to-app-home-lib-directory/2012
    doLast {
        def windowsScriptFile = file getWindowsScript()
        def unixScriptFile = file getUnixScript()
        windowsScriptFile.text = windowsScriptFile.text.replace('%APP_HOME%\\lib\\config', '%APP_HOME%\\config')
        unixScriptFile.text = unixScriptFile.text.replace('$APP_HOME/lib/config', '$APP_HOME/config')
    }
}

spotless {
    java {
        googleJavaFormat()
    }
}