build.gradle

plugins {
    id "java"
    id "eclipse"
    id "idea"
    id "jaci.openrio.gradle.GradleRIO" version "2018.02.17"
    //id "com.github.sherter.google-java-format" version "0.6"
}
repositories {
    jcenter()
    mavenCentral()
}

def TEAM = 1701
def ROBOT_CLASS = "org.usfirst.frc.team1701.robot.Robot"

// Define my targets (RoboRIO) and artifacts (deployable files)
// This is added by GradleRIO's backing project EmbeddedTools.
deploy {
    targets {
        //noinspection UnnecessaryQualifiedReference
        target("roborio", jaci.openrio.gradle.frc.RoboRIO) {
            team = TEAM
        }
    }
    artifacts {
        //noinspection UnnecessaryQualifiedReference
        artifact('frcJava', jaci.openrio.gradle.frc.FRCJavaArtifact) {
            targets << "roborio"
        }
    }
}

// Defining my dependencies. In this case, WPILib (+ friends), CTRE Toolsuite (Talon SRX)
// and NavX.
dependencies {
    //noinspection GroovyAssignabilityCheck
    compile wpilib()
    //noinspection GroovyAssignabilityCheck,GroovyAssignabilityCheck
    compile ctre()
    //noinspection GroovyAssignabilityCheck
    compile navx()
}

// Setting up my Jar File. In this case, adding all libraries into the main jar ('fat jar')
// in order to make them all available at runtime. Also adding the manifest so WPILib
// knows where to look for our Robot Class.
jar {
    from configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
    //noinspection UnnecessaryQualifiedReference
    manifest jaci.openrio.gradle.GradleRIOPlugin.javaManifest(ROBOT_CLASS)
}

task wrapper(type: Wrapper) {
    gradleVersion = '4.4'
}