build.gradle

plugins {
    id "cpp"
    id "google-test-test-suite"
    id "edu.wpi.first.GradleRIO" version "2024.3.2"
}

// Define my targets (RoboRIO) and artifacts (deployable files)
// This is added by GradleRIO's backing project DeployUtils.
deploy {
    targets {
        roborio(getTargetTypeClass('RoboRIO')) {
            // Team number is loaded either from the .wpilib/wpilib_preferences.json
            // or from command line. If not found an exception will be thrown.
            // You can use getTeamOrDefault(team) instead of getTeamNumber if you
            // want to store a team number in this file.
            team = project.frc.getTeamNumber()
            debug = project.frc.getDebugOrDefault(false)

            artifacts {
                // First part is artifact name, 2nd is artifact type
                // getTargetTypeClass is a shortcut to get the class type using a string

                frcCpp(getArtifactTypeClass('FRCNativeArtifact')) {
                }

                // Static files artifact
                frcStaticFileDeploy(getArtifactTypeClass('FileTreeArtifact')) {
                    files = project.fileTree('robot')
                    directory = '/home/lvuser/deploy'
                }
            }
        }
    }
}

def deployArtifact = deploy.targets.roborio.artifacts.frcCpp

// Set this to true to enable desktop support.
def includeDesktopSupport = true

// Set to true to run simulation in debug mode
wpi.cpp.debugSimulation = false

// Default enable simgui
wpi.sim.addGui().defaultEnabled = true
// Enable DS but not by default
wpi.sim.addDriverstation().defaultEnabled = true

model {
    components {
        frcUserProgram(NativeExecutableSpec) {
            targetPlatform wpi.platforms.roborio
            if (includeDesktopSupport) {
                targetPlatform wpi.platforms.desktop
            }

            sources.cpp {
                source {
                    srcDir 'src'
                    include '**/*.cpp', '**/*.cc'
                }
                exportedHeaders {
                    srcDir 'src'
                }
            }
        
            // Set deploy task to deploy this component
            deployArtifact.component = it

            // Enable run tasks for this component
            wpi.cpp.enableExternalTasks(it)

            // Enable simulation for this component
            wpi.sim.enable(it)
            // Defining my dependencies. In this case, WPILib (+ friends), and vendor libraries.
            wpi.cpp.vendor.cpp(it)
            wpi.cpp.deps.wpilib(it)
        }
    }
    testSuites {
        frcUserProgramTest(GoogleTestTestSuiteSpec) {
            testing $.components.frcUserProgram

            sources.cpp {
                source {
                    srcDir 'test'
                    include '**/*.cpp'
                }
            }

            // Enable run tasks for this component
            wpi.cpp.enableExternalTasks(it)

            wpi.cpp.vendor.cpp(it)
            wpi.cpp.deps.wpilib(it)
            wpi.cpp.deps.googleTest(it)
        }
    }
}

//==============================================================================
// returns a directory or file within the sdk dir.
String sdkDir(String dir = "") {
    String out = projectDir.toString()
    out += "/vendordeps/sdk"
    if (! dir.isEmpty())
        out += "/" + dir
    return out
}

// Guesses an sdk slug (linux64, roborio, msvc, darwin) for a given target name.
String sdkSlugForTargetName (String name) {
    String lname = name.toLowerCase();
    
    if (lname.contains ("linuxx86-64")) {
        return "linux64"
    } else if (lname.contains ("linuxathena")) {
        return "roborio"
    } else if (lname.contains ("windowsx86-64")) {
        return "msvc"
    } else if (lname.contains ("darwin")) {
        return "macos"
    }

    return "unknown"
}

tasks.withType(CppCompile).configureEach {
    String sdkSlug = sdkSlugForTargetName(name)
    if (false) {
        includes {
            sdkDir (sdkSlug + "/include")
            "vendordeps/luajit/src"
        }
    } else {
        includes {
            sdkDir (sdkSlug + "/include")
            sdkDir (sdkSlug + "/include/luajit-2.1")
        }
    }
}

tasks.withType(LinkExecutable).configureEach {
    String platform = targetPlatform.get().name
    if (platform == 'linuxx86-64') {
        linkerArgs.addAll '-L', sdkDir('linux64/lib'), '-lluajit-5.1'
    } else if (platform == 'linuxathena') {
        linkerArgs.addAll '-L', sdkDir('roborio/lib'), '-lluajit-5.1'
    } else if (platform == 'windowsx86-64') {
        linkerArgs.addAll  sdkDir('msvc/lib/lua51.lib')
    }
}

 task clangFormat {
     doLast {
         exec {
             workingDir "${projectDir}"
             executable 'python3'
             args "${projectDir}/util/format.py"
         }
     }
 }